====== Military ======

===== Fleet details =====
<view:table>
template {
  user:brend:template:military#fleet_table_header
  user:brend:template:military#fleet_table_row
}
fields {
?fleet [ref]
?faction [ref]
?army [ref]
?commander[ref]
?upkeep
?attack_outer[dot]: Outer Attack
?attack_middle[dot]: Middle Attack
?attack_inner[dot]: Inner Attack
?defence_outer[dot]: Outer Defence
?defence_middle[dot]: Middle Defence
?defence_inner[dot]: Inner Defence
?status
?effectiveness
?sector
}

?fleet is a: military_fleet
?fleet Faction [ref]: ?faction
?faction Type[rule]: PC
?fleet Level of Activity: ?status
?fleet Sector [sector]: ?sector
?fleet Effectiveness Levels [effectiveness]: ?effectiveness

optional {
  ?fleet Jedi Commander [ref]: ?commander
}

optional {
  ?army is a: army
  ?army Attached to [ref]: ?fleet
}

union {
  {
  ?_upkeep is a: upkeep
  ?_upkeep on [ref]: ?fleet
  ?_upkeep Upkeep: ?upkeep
  ?_upkeep != ?fleet
  }
  {
  ?fleet Upkeep: ?upkeep
  }
}


?fleet Outer Attack           : ?attack_outer
?fleet Middle Attack          : ?attack_middle
?fleet Inner Attack           : ?attack_inner
?fleet Outer Defence          : ?defence_outer
?fleet Middle Defence         : ?defence_middle
?fleet Inner Defence          : ?defence_inner

sort {
  ?faction
  ?fleet
}
group {
  ?faction
  ?fleet
  ?army
  ?commander
  ?attack_outer
  ?attack_middle
  ?attack_inner
  ?defence_outer
  ?defence_middle
  ?defence_inner
  ?status
  ?effectiveness
  ?sector
}
ui {
  Army {
    sort: no
  }
  Commander {
    sort: no
  }
  Fleet {
    filter: text
  }
  Faction {
    filter: select
  }
  Status {
    filter: select
  }
  Effectiveness {
    filter: select
  }
  Sector {
    filter: select
  }
}
</view>

===== Army details =====
<view:table>
template {
  user:brend:template:military#army_table_header
  user:brend:template:military#army_table_row
}
fields {
?army [ref]
?faction[ref]
?attached_to [ref]
?upkeep
?attack_outer[dot]: Outer
?attack_middle[dot]: Middle
?attack_inner[dot]: Inner
?defence_outer[dot]: Outer
?defence_middle[dot]: Middle
?defence_inner[dot]: Inner
}

?army is a: army
?army Faction [ref]: ?faction
?faction Type[rule]: PC
?army Upkeep: ?upkeep

optional {
  ?army attached to [ref]: ?attached_to
}

?army Outer Attack           : ?attack_outer
?army Middle Attack          : ?attack_middle
?army Inner Attack           : ?attack_inner
?army Outer Defence          : ?defence_outer
?army Middle Defence         : ?defence_middle
?army Inner Defence          : ?defence_inner

sort {
  ?faction
  ?army
}
</view>

===== Hyperspace Monitoring Grids =====
<table ?faction [faction::icon] "" ?faction [ref] ?grid ?sector>
?grid is a: hyperspace_monitoring_grid
?grid Faction [ref]: ?faction
?grid Sector [ref]: ?sector

ui {
  #1 {
    sort: no
  }
  Faction {
    filter: select
  }
}
</table>

===== Defence Forces =====
<table ?force [imagelink::64] "" ?force[ref] ?faction [faction::icon] "" ?faction [ref] ?on[imagelink::64] "" ?on[ref]>
?force is a: defence_force
?force Faction [ref]: ?faction
?force On [ref]: ?on

ui {
  #1 {
    sort: no
  }
  Faction {
    filter: select
  }
}
</table>

===== All fleets =====
<table ?fleet [ref] ?faction [faction::icon] "" ?faction [ref] ?sector ?status ?upkeep ?effectiveness>
?fleet is a: military_fleet
?fleet Faction [ref]: ?faction
?fleet Sector [ref]: ?sector
?fleet Level of Activity: ?status
?fleet Effectiveness Levels [effectiveness]: ?effectiveness

optional {
  ?fleet Upkeep: ?upkeep
}

ui {
  #1 {
    sort: no
  }
  Faction {
    filter: select
  }
  Status{
    filter: select
  }
  Sector {
    filter: text
  }
  Fleet {
    filter: text
  }
}
</table>

